home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 1 / Cream of the Crop 1.iso / EDITOR / TDRAW451.ARJ / MAKEQLB.BAT < prev    next >
DOS Batch File  |  1992-04-15  |  3KB  |  110 lines
  1. ECHO OFF
  2.  
  3. IF NOT "%1"=="" GOTO START
  4. ECHO  
  5. ECHO MAKEQLB takes TheDraw QuickBasic object files and incorporates them into a
  6. ECHO QuickBasic Library (for use in the integrated environment), plus a parallel
  7. ECHO link library (.LIB) file.  Non-TheDraw object files and libraries may also
  8. ECHO be included if you desire.
  9. ECHO  
  10. ECHO The following files must be present in the same directory:
  11. ECHO   LINK.EXE, LIB.EXE, BQLB40.LIB or BQLB45.LIB, QB4UTIL.LIB, and
  12. ECHO   the object files you want in the libraries.
  13. ECHO  
  14. ECHO ─────────────────────────────────────────────────────────────────────────── 
  15. ECHO  
  16. ECHO Usage:    MAKEQLB library [file1] [file2] [file3] etc...
  17. ECHO  
  18. ECHO           Do not put a file extension in the "library" parameter, as
  19. ECHO           the extensions .QLB and .LIB are assumed.
  20. ECHO  
  21. ECHO  
  22. ECHO Example:  MAKEQLB test image1.OBJ image2.OBJ image3.OBJ mycode.LIB
  23. ECHO  
  24. ECHO           Produces TEST.QLB -and- TEST.LIB containing the three object
  25. ECHO           files plus the contents of the library file MYCODE.LIB.
  26. ECHO  
  27. GOTO DONE
  28.  
  29. :START
  30. IF NOT EXIST LINK.EXE GOTO MISSINGFILE
  31. IF NOT EXIST LIB.EXE GOTO MISSINGFILE
  32. IF NOT EXIST QB4UTIL.LIB GOTO MISSINGFILE
  33. IF EXIST BQLB40.LIB GOTO GOTFILES
  34. IF EXIST BQLB45.LIB GOTO GOTFILES
  35.  
  36. :MISSINGFILE
  37. ECHO  
  38. ECHO Error!  MAKEQLB needs all of the following files in the current directory:
  39. ECHO   LINK.EXE
  40. ECHO   LIB.EXE
  41. ECHO   BQLB40.LIB
  42. ECHO   BQLB45.LIB
  43. ECHO   QB4UTIL.LIB
  44. ECHO   TheDraw object files (.OBJ) to included in libraries
  45. ECHO  
  46. ECHO Processing halted.
  47. GOTO DONE
  48.  
  49. :GOTFILES
  50. ECHO  
  51. ECHO Processing TheDraw Quick Library...
  52. SET libname=%1
  53. IF NOT EXIST %libname%.LIB GOTO NEWLIB
  54. ECHO Updating:  %libname%.LIB
  55. GOTO LIBLOOP
  56.  
  57. :NEWLIB
  58. ECHO Creating:  %libname%.LIB
  59. LIB %libname%.LIB+QB4UTIL.LIB; >ERRLOG
  60. IF ERRORLEVEL==1 GOTO LIBERROR
  61. GOTO LIBLOOP
  62.  
  63. :LIBOK
  64. SHIFT
  65. :LIBLOOP
  66. IF "%2"=="" GOTO QLBMAKE
  67. IF EXIST %2 GOTO LIBADD
  68. IF EXIST %2.OBJ GOTO LIBADD
  69. IF NOT EXIST %2.LIB GOTO INVALIDPARAM
  70.  
  71. :LIBADD
  72. ECHO   Adding:  %2
  73. LIB %libname%.LIB -%2; >ERRLOG
  74. LIB %libname%.LIB +%2; >ERRLOG
  75. IF NOT ERRORLEVEL==1 GOTO LIBOK
  76.  
  77. :LIBERROR
  78. ECHO  
  79. ECHO Fault occured while attempting to add "%2" to library "%libname%.LIB".
  80. TYPE ERRLOG
  81. IF EXIST ERRLOG DEL ERRLOG
  82. ECHO  
  83. ECHO To end processing, press [CTRL-C] or
  84. PAUSE
  85. GOTO LIBOK
  86.  
  87. :INVALIDPARAM
  88. ECHO  
  89. ECHO Aborting.  Unable to find any object file or library named: %2
  90. GOTO Done
  91.  
  92. :QLBMAKE
  93. IF EXIST %libname%.QLB ECHO Updating:  %libname%.QLB
  94. IF NOT EXIST %libname%.QLB ECHO Creating:  %libname%.QLB
  95. IF EXIST BQLB40.LIB LINK /Q /NOE /NOD %libname%.LIB, %libname%.QLB,ERRLOG.MAP,BQLB40.LIB; >ERRLOG
  96. IF EXIST BQLB45.LIB LINK /Q /NOE /NOD %libname%.LIB, %libname%.QLB,ERRLOG.MAP,BQLB45.LIB; >ERRLOG
  97. IF NOT ERRORLEVEL==1 GOTO QLBDONE
  98.  
  99. ECHO  
  100. ECHO Fault occured while creating quick library "%libname%.QLB".
  101. TYPE ERRLOG
  102.  
  103. :QLBDONE
  104. IF EXIST %libname%.BAK DEL %libname%.BAK
  105. SET LIBNAME=
  106.  
  107. :DONE
  108. IF EXIST ERRLOG DEL ERRLOG
  109. IF EXIST ERRLOG.MAP DEL ERRLOG.MAP
  110.